[解决了]怎么阻止htmlayout打开超链接?

winner

import win.ui;
/*DSG{{*/
var winform = ..win.form( bottom=423;parent=...;text="aardio Form";right=713 )
winform.add(  )
/*}}*/

import web.layout
import process;


var w = web.layout(winform)
w.html = /**
        <a href="http://www.baidu.com">点击进入百度</a>
**/
w.onHyperlinkClick = function (ltTarget,ltEle,reason,behaviorParams) {
    process.execute(ltEle.getAttribute("href"))
}

winform.show()
win.loopMessage();

---

我想实现,点击之后用IE打开超链接,
但是像上面这样写,IE打开之后,他又在当前页面跳到了百度...

quicker

最好不要使用单字母变量名.  

---

import win.ui;
/*DSG{{*/
var winform = ..win.form( bottom=423;parent=...;text="aardio Form";right=713 )
winform.add(  )
/*}}*/

import process;
import web.layout

var wbLayout = web.layout(winform)
wbLayout.html = /**
        <a href="http://www.baidu.com">点击进入百度</a>
**/

//在捕获模式(消息自上向下传递)下拦截消息
wbLayout.sinking = {
    onHyperlinkClick = function (ltTarget,ltEle,reason,behaviorParams) {
        process.execute( ltEle.href )
        return true;//取消默认行为
    }
}

winform.show()
win.loopMessage()

winner

quicker 发表于 2012-7-20 13:23
最好不要使用单字母变量名.  

---

多谢!!!!!!!!

quicker

创建一个behavior也可以

---

import win.ui;

/*DSG{{*/
var winform = ..win.form( bottom=423;parent=...;text="aardio Form";right=713 )
winform.add(  )
/*}}*/

import web.layout
var wbLayout = web.layout(winform)

import process;
namespace web.layout.behavior.shellLink{
    sinking = {
        onHyperlinkClick = function (ltTarget,ltEle,reason,behaviorParams) {
            ..process.execute( ltEle.href )
            return true;//取消默认行为
        }
    }   
}

wbLayout.html = /**
        <a href="http://www.baidu.com" style="behavior:~shell-link;//添加行为">点击进入百度</a>
**/

winform.show()
win.loopMessage()

cnruby

import win.ui;
/*DSG{{*/
var winform = ..win.form( bottom=423;parent=...;text="aardio Form";right=713 )
winform.add(  )
/*}}*/
import web.layout
import process;

var w = web.layout(winform)
w.html = /**
        <a href="http://www.baidu.com" target="_blank">点击进入百度</a>
**/
w.onHyperlinkClick = function (ltTarget,ltEle,reason,behaviorParams) {
    process.execute(ltEle.getAttribute("href"))
}
winform.show()
win.loopMessage();

winner

cnruby 发表于 2012-7-20 14:42
import win.ui;
/*DSG{{*/
var winform = ..win.form( bottom=423;parent=...;text="aardio Form";right=7 ...

这个也好使...