遇到问题，不知道是不是写错了

fexzi

这是我的代码：

1. import win.ui;
   
2. import process;
   
3. /*DSG{{*/
   
4. var winform = win.form( bottom=400;parent=...;right=479;text="aardio Form" )
   
5. winform.add(
   
6. button2={ bottom=40;text="显示所有进程";left=296;top=8;z=4;right=376;cls="button" };
   
7. listview={ bgcolor=16777215;bottom=392;right=472;left=8;top=48;z=6;edge=1;cls="listview" };
   
8. edit={ bottom=32;right=200;left=104;top=8;z=2;edge=1;cls="edit" };
   
9. button={ bottom=40;text="KILL";left=208;top=8;z=3;right=288;cls="button" };
   
10. static={ bottom=72;right=160;left=8;top=16;transparent=1;notify=1;text="请输入进程PID";z=1;cls="static" };
    
11. button3={ bottom=40;text="刷新";left=384;top=8;z=5;right=464;cls="button" }
    
12. )
    
13. /*}}*/
    
14. 
    
15. winform.listview.onnotify = function(id,code,ptr){
    
16.         //var nmdr = win.ui.NMHDR(); raw.convert( ptr,nmdr );;
    
17.        
    
18.        
    
19. }
    
20. winform.static.oncommand = function(id,event){
    
21.         //winform.msgbox( winform.static.text );
    
22.        
    
23.        
    
24. }
    
25. winform.wndproc = function(hwnd,message,wParam,lParam){
    
26.         select( message ) {
    
27.                 case 0x205/*_WM_RBUTTONUP*/{
    
28.                         //鼠标右键弹起,下面获取坐标
    
29.                         var x,y = win.getMessagePos(lParam);
    
30.                        
    
31.                 }
    
32.                 else{
    
33.                        
    
34.                 }
    
35.         }
    
36.         //无返回值则继续调用默认回调函数
    
37. }
    
38. 
    
39. winform.button.oncommand = function(id,event){
    
40.         //winform.msgbox( winform.button.text );
    
41.         prcId = winform.edit.text
    
42.         killPrc(prcId);
    
43.        
    
44. }
    
45. GetProcessMemoryInfo = ::Psapi.api("GetProcessMemoryInfo","int(pointer hProcess,struct& ppsmemCounters,int cb)")
    
46. 
    
47. PROCESS_MEMORY_COUNTERS= class{
    
48.     int cb;
    
49.     int PageFaultCount;
    
50.     int PeakWorkingSetSize; //物理内存的最大值
    
51.     int WorkingSetSize;     //物理内存的大小
    
52.     int QuotaPeakPagedPoolUsage;
    
53.     int QuotaPagedPoolUsage;
    
54.     int QuotaPeakNonPagedPoolUsage;
    
55.     int QuotaNonPagedPoolUsage;
    
56.     int PagefileUsage;      //虚拟内存大小
    
57.     int PeakPagefileUsage;  //虚拟内存的最大值
    
58. }
    
59. 
    
60. mem=PROCESS_MEMORY_COUNTERS()
    
61. 
    
62. 
    
63. 
    
64. killPrc = function(prcId){
    
65. 
    
66. }
    
67. i=0
    
68. for processEntry in process.each( ".*.exe" ) {  
    
69.      i++;  
    
70.      prc=process(processEntry.th32ProcessID)
    
71.      GetProcessMemoryInfo(prc.handle,mem,raw.sizeof(mem))
    
72.   procName=processEntry.szExeFile //进程名称
    
73.   procId=processEntry.th32ProcessID //进程PID
    
74.   procMem=mem.WorkingSetSize/1024 ++ "K"
    
75.    winform.listview.addItem("",i) //插入的行数
    
76.    winform.listview.setItemText(procName,i,1)
    
77.    winform.listview.setItemText(tostring(procId),i,2)
    
78.    winform.listview.setItemText(procMem,i,3)
    
79.    
    
80. }
    
81. 
    
82. tlv={ "进程名称";"进程PID";"进程使用内存" }
    
83. for ( k,v in tlv ){
    
84. if(v="进程名称"){
    
85.                         len=150;
    
86.                 }elseif(v="进程PID"){
    
87.                         len=150;
    
88.                 }else {
    
89.                 len=158;
    
90.                 }
    
91.                 winform.listview.insertColumn(v,len,i,0x2/*_LVCFMT_LEFT*/)
    
92.                
    
93. }
    
94. 
    
95. winform.text="进程管理器"
    
96. winform.show()
    
97. win.loopMessage();
    
98. return winform;
    

复制代码

第二列和第三列的数值没有出来？

编程

规范代码重新写了一遍, 问题自然就没有了.
代码不规范，思路也就乱，问题也就多，找起来也很痛苦，

import win.ui;
import process;
/*DSG{{*/
var winform = ..win.form( bottom=400;parent=...;right=479;text="aardio Form" )
winform.add(
btnListProcess={ bottom=40;text="显示所有进程";left=296;top=8;z=4;right=376;cls="button" };
listview={ bgcolor=16777215;bottom=392;right=472;left=8;top=48;z=6;edge=1;cls="listview" };
button={ bottom=40;text="KILL";left=208;top=8;z=3;right=288;cls="button" };
static={ bottom=72;right=160;left=8;top=16;transparent=1;notify=1;text="请输入进程PID";z=1;cls="static" };
editProcId={ bottom=32;right=200;left=104;top=8;z=2;edge=1;cls="edit" };
btnRefresh={ bottom=40;text="刷新";left=384;top=8;z=5;right=464;cls="button" }
)
/*}}*/

//列表视图添加列
tlv={ { "进程名称";150};{ "进程PID";150};{ "进程使用内存";-1} }
for ( i,column in tlv ){
     winform.listview.insertColumn(column[1],column[2] );
}

//杀除进程  
winform.button.oncommand = function(id,event){
   var prcId = tonumber(winform.editProcId.text)
   process(prcId).terminate()
}

//列表视图响应鼠标点击
winform.listview.onnotify = function(id,code,ptr){
   
    select(code) {
        case  0xFFFFFF9B/*_LVN_ITEMCHANGED*/ {
            var nm = winform.listview.getNotifyMessage(code,ptr)
            if(winform.listview.selIndex){
                winform.editProcId.text = winform.listview.getItemText(nm.iItem,2)
            }
        }
        case 0xFFFFFFFB/*_NM_RCLICK*/  {
            var x,y = mouse.getPos()
            //弹出菜单
        }
    }
}

//获取进程内存
GetProcessMemoryInfo = ::Psapi.api("GetProcessMemoryInfo","int(pointer hProcess,struct& ppsmemCounters,int cb)")
PROCESS_MEMORY_COUNTERS= class{
    int cb;
    int PageFaultCount;
    int PeakWorkingSetSize; //物理内存的最大值
    int WorkingSetSize;     //物理内存的大小
    int QuotaPeakPagedPoolUsage;
    int QuotaPagedPoolUsage;
    int QuotaPeakNonPagedPoolUsage;
    int QuotaNonPagedPoolUsage;
    int PagefileUsage;      //虚拟内存大小
    int PeakPagefileUsage;  //虚拟内存的最大值
}
memory_counters =PROCESS_MEMORY_COUNTERS()

import fsys;
listProcess = function(){
    winform.listview.clear();
    win.delay(500);
   
    for processEntry in process.each( ".*.exe" ) {   
   
        var prc=process(processEntry.th32ProcessID)
        if(!prc) continue;
        
        GetProcessMemoryInfo(prc.handle,memory_counters,raw.sizeof(memory_counters))
        procName=processEntry.szExeFile //进程名称
        procId=processEntry.th32ProcessID //进程PID
        procMem= fsys.formatSize(memory_counters.WorkingSetSize)
        
        var row = winform.listview.addItem(procName ) //插入的行数
        winform.listview.setItemText(tostring(procId),row,2)
        winform.listview.setItemText(procMem,row,3)
    }   
}
listProcess();

winform.btnRefresh.oncommand = function(id,event){
    listProcess();
}

winform. btnListProcess.oncommand = function(id,event){
    listProcess();  
}

winform.text="进程管理器"
winform.show()

win.loopMessage();
return winform;

编程

你先添加每个列的数据, 可是这时候这些列还没有创建.
应当先创建listview的所有列, 再填充数据.

编码的时候注意规范, 把初始化的代码写在前面.

fexzi

非常感谢楼上提出的解答，是啊，因为自己是初学者，一下子思路感觉有点乱了，也看了许多的例子，现在在开始写一些代码，刚开始的，确实遇到不少问题

fexzi

再问一下，这边var row = winform.listview.addItem(procName ) //插入的行数
        winform.listview.setItemText(tostring(procId),row,2)
        winform.listview.setItemText(procMem,row,3)
这样第一列的数据就自动插入了？

fexzi

我自己试了下，确实在定义局部变量var row = winform.listview.addItem(procName ) ，第一列就已经插入了，我只是遇到这个小问题，后面的几个控件功能都还没有去写，没有想到，编程同志全部给完成了。

编程

一般常见的需求，标准库的函数一般也会考虑到了，
用的时候注意看一下代码提示，或者到相应的库看一下函数源码。
象listview的源码在 win.ui.ctrl.listview 里。

一个就是写代码的时候注意整理清晰，注意书写规范。
另外一个就是遇到问题留心你忽略的细节，这样可以少走很多弯路。

fexzi

有一些代码都是写好的直接拷过来，只知道这样可以实现某功能，但具体的为什么要这样写，还不是很清楚，有好的办法？