自动玩扫雷,鼠标模拟+远程call

www378660084

import process;
import winex;
import mouse;
import key;

//地址是在我的xp机器上找到的,不知道一不一样~~~~
/*
MOD:
    模式
    0:call模式
    1:鼠标模拟模式
*/
var MOD = 1
var CALLADDR = 0x010037E1   //call地址
var DATABASE = 0x1005340    //棋盘基址
var SETBASE = 0x01005330    //设置基址+0:雷点个数 +4:棋盘宽 +8:棋盘高
var XYBASE = 0x01005118     //call参数:XYBASE:x   XYBASE+4:y


var prc = process("winmine.exe") //创建扫雷进程

var act,hwnd;

if(MOD){  //鼠标模式
    hwnd = winex.waitVisible("扫雷");  //获取窗口句柄
    win.getActive(hwnd);                //激活窗口
    x,y,cx,cy=win.getPos(hwnd);         //获取窗口坐标
}else{  //call模式
    act = prc.remoteApi("void()", CALLADDR);  //获取远程call
}

var width = prc.readNumber(SETBASE+4,"INT")
var height = prc.readNumber(SETBASE+8,"INT")
for(j=1;height)
for(i=1;width)
{
    n = prc.readNumber(DATABASE+i+32*j,"byte")  //棋盘基址+x+y*32=棋盘点的值
    /*
        n:棋盘点的值
        未点击时:无雷:0f;;;有雷,8f (有用)
        点击后:无雷:4x,x=周围雷的个数;;;有雷8x
    */
    if(n==0x0f)  
    {
        if(MOD){
            mouse.move(x+4+16*i,y+96+16*j,true);  //移动到坐标点
            mouse.click();                      //点击
            //sleep(500)  
        }else{
            prc.writeNumber(XYBASE,i,"INT")  //写X坐标
            prc.writeNumber(XYBASE+4,j,"INT")  //写Y坐标
            act();                              //点击函数
        }
    }
}
prc.free();         //释放句柄

JacenHe

改进了一下，可以在 Win10 上直接运行，
另外，其实 aardio 可以直接在外部进程内存读写结构体：

//自动扫雷
import winex;
import mouse;
import process;

//启动扫雷游戏
import process.winmine;
var prcs = process.winmine();

//自进程内存读取结构体，写内存用 prcs.write 函数。
var setting = prcs.readStruct(0x01005330,{
    INT count; //雷点个数
    INT width;//棋盘宽
    INT height;//棋盘高
})

if(false){  
    //方法一：鼠标模式
    hwnd = winex.waitVisible("扫雷");//获取窗口句柄
    win.showForeground(hwnd);//激活窗口

    sweep = function(x,y){
        x,y = win.toScreen(hwnd,1+16*x,50+16*y); //转换为屏幕坐标
        mouse.click(x,y,true); //在指定坐标模拟鼠标单击
    }
}
else{  
    //方法二：远程Call( 直接调用 EXE 里的函数 )
    var addrCall = 0x010037E1 //call地址
    var addrPoint = 0x01005118 //call参数:addrCallPoint:x   addrCallPoint+4:y
   
    //获取远程call
    var act = prcs.remoteApi("void()", addrCall);
   
    sweep = function(x,y){
        //写入结构体到外部进程
        prcs.write(addrPoint,{
            INT x = x;
            INT y = y;
        })
        
        act(); //远程Call 点击函数
        thread.delay(10); //加点延时
    }
}

var addrDatabase = 0x1005340 //棋盘基址
for(y=1;setting.height){
    for(x=1;setting.width){
        //未点击时:无雷:0f;;;有雷,8f (有用),点击后:无雷:4x,x=周围雷的个数;;;有雷8x
        n = prcs.readNumber(addrDatabase+x+32*y,"byte") //棋盘基址+x+y*32=棋盘点的值
        if(n==0x0f) sweep(x,y);
    }
}

//释放进程对象
prcs.free();

低调点

在IDE里 右键复制到HTML  然后论坛发帖选择高级模式  
这样看起来效果更好 代码有高亮  层次更清晰....

www378660084

xj199241 发表于 2011-10-11 22:05
在IDE里 右键复制到HTML  然后论坛发帖选择高级模式  
这样看起来效果更好 代码有高亮  层次更清晰....

改过来了,谢谢提醒

编程

{:soso_e179:} 楼主很强，附小修改后的代码，供参考

import key;
import mouse;
import process;
import winex;
import win.ui;
/*DSG{{*/
var winform = win.form( text="aardio Form";right=346;bottom=138 )
winform.add(
btnCall={ bottom=88;text="Call自动扫雷";left=187;top=49;z=2;right=291;cls="button" };
btnMouse={ bottom=88;text="鼠标自动扫雷";left=52;top=49;z=1;right=156;cls="button" }
)
/*}}*/

var CALLADDR = 0x010037E1   //call地址
var DATABASE = 0x1005340    //棋盘基址
var SETBASE = 0x01005330         //设置基址+0:雷点个数 +4:棋盘宽 +8:棋盘高
var XYBASE = 0x01005118                //call参数:XYBASE:x   XYBASE+4:y

sweeper  = function(byMouse){

    var prc = process("winmine.exe") //创建扫雷进程
    //这里最好指定进程ID,不然会找到你刚发的贴子窗口,因为浏览器标题栏也有"扫雷"这几个字
    hwnd = winex.waitVisible( "<扫雷>|<Minesweeper>",,,,,prc.id );  //获取窗口句柄      
    win.setForeground(hwnd) //外部进程最好用这个函数              
    var x,y,cx,cy=win.getPos(hwnd);    //获取窗口坐标
   
    var width = prc.readNumber(SETBASE+4,"INT")
    var height = prc.readNumber(SETBASE+8,"INT")
    var Act_c = prc.remoteApi("void()", CALLADDR);  //获取远程call
    for(j=1;height){
        for(i=1;width) begin
            var n = prc.readNumber(DATABASE+i+32*j,"byte")  //棋盘基址+x+y*32=棋盘点的值
            // 未点击时:无雷:0f;;;有雷,8f (有用) 点击后:无雷:4x,x=周围雷的个数;;;有雷8x
            if(n==0x0f) {
                if(byMouse){
                    mouse.move(x+4+16*i,y+96+16*j,true);  //移动到坐标点
                    mouse.click();  
                    win.delay(10); //加点延时,不然太快完成看不到过程
                }
                else {
                    prc.writeNumber(XYBASE,i,"INT")  //写X坐标
                    prc.writeNumber(XYBASE+4,j,"INT")  //写Y坐标
                    Act_c();//点击函数
                    win.delay(100); //加点延时,不然太快完成看不到过程
                }
            };
        end;
    }
    prc.free();  //释放句柄
}

winform.btnCall.oncommand = function(){
    sweeper(false)
}
  
winform.btnMouse.oncommand= function(){
    sweeper(true)
}

winform.show();
import win.version
if( ! win.version.isXp ) {
    winform.msgboxErr("此程序仅用于XP系统扫雷游戏")
    winform.btnCall.disabled=true;
    winform.btnMouse.disabled=true;
}

win.loopMessage();

www378660084

编程 发表于 2011-10-11 22:34
楼主很强，附小修改后的代码，供参考

import key;

看了改动的几处,都很不错,3ks,昨晚不能上网抽空研究一下aardio,写了这个玩意,感觉aardio用起来真的很不错~
论坛的代码要能加上高亮就好了

fyy

远程call看起来有难度，不错的范例

ghl781258

很好的学习资料。收藏备用了！

Auto

强大{:soso_e100:}，学习。

qwaq001

很好的学习资料。

xx44t10

楼上好牛啊。不错。

maiev

顶。aardio真的不错

sj798

顶起来，好好学习

ddaw

很好的学习材料

dafei2599

Call是怎么找到的？共享一下方法呗，嘿嘿

善良的自行车

我晕，我想知道，函数基值这样的东西是怎么查的？

满月星光

用CE 或OD 不知我说的可行。

lukewang

{:soso_e179:}
高！

boot

Cheat Engine

ollydbg

Dependency Walker  这个最简单了

洋葱。

马克。  留着学习。