请教一下循环多次播放声音文件只播放一次的问

aaruser

程序里面有个提示的功能，需要播放声音，然后设置了循环播放n次，例如是3，可是循环后只有一次播放
尝试用线程播放，发现干脆没声音了，没研究出什么地方出错了，看了Jacen的关于线程的那个帖子，还是没能弄好

1. import win.ui;
   
2. import web.form;
   
3. import crypt;
   
4. 
   
5. import fsys;
   
6. import fsys.media;
   
7. import win.util.tray;//导入汽球提示支持库
   
8. 
   
9. import time;
   
10. import fsys.file;
    
11. import thread;
    
12. 
    
13. 
    
14. /*DSG{{*/
    
15. var winform = win.form(text="winform";right=1174;bottom=839;width=1920)
    
16. winform.add(
    
17. button={cls="button";text="声音测试";left=1009;top=807;right=1170;bottom=837;z=4};
    
18. custom={cls="custom";text="custom";left=6;top=-51;right=1170;bottom=789;db=1;dl=1;dr=1;dt=1;z=1};
    
19. edit={cls="edit";left=875;top=3;right=1168;bottom=566;db=1;dr=1;dt=1;edge=1;multiline=1;z=2};
    
20. edit2={cls="edit";text="Edit";left=876;top=581;right=1168;bottom=625;edge=1;multiline=1;z=3}
    
21. )
    
22. /*}}*/
    
23. 
    
24. winform.button.oncommand = function(id,event){ //事件必须放在show之前
    
25.         thread.invoke(t_alert,winform)
    
26.         //t_alert(5);  //此处直接调用可以播放声音，但是只有播放一次
    
27.         /*thread.create(function(winform){
    
28.                 winform.t_alert(3);
    
29.         },winform)*/
    
30. }
    
31. 
    
32. t_alert=function(num=3){ //播放声音提醒
    
33. 
    
34.    for(i=1;num;1){
    
35.           
    
36.    fsys.media.playSound("\res\v.wav",0x1/*_SND_ASYNC*/);
    
37.    
    
38.    }
    
39.         win.util.tray(winform).pop( "OK" ) //看看节点取的是否正确
    
40.    
    
41. }
    
42. 
    
43. thread.invoke(t_alert)
    
44. 
    
45. 
    
46. winform.show();
    
47. win.loopMessage();

复制代码

谢谢帮助

JacenHe

你不是循环播放多次声音，而是同时播放多个声音，一张嘴不能同时说3句话，playSound也一样。你也没有到线程里播放声音，只是在线程里发了指令又去调用界面线程的函数 - 犯了同样的错误。

你也没怎么“研究”过 - 当然也就研究不出结果，至少能看出来你没有看过fsys.media的文档以及微软相关接口的文档 。
要想循环播放，可以使用 media.play("wait") 等上一次播放结束再 media.seek(1) 回到开始重新播放，这个就好像人吃饭，你要吃三碗，得等第一碗吃完了再吃下一碗，而不是三碗饭往嘴里一倒：咦.........明明循环给你喂了三碗，你怎么才吃了一口就不行了？！

例子：

import win.ui;
/*DSG{{*/
var winform = win.form(text="aardio form")
winform.add(
button={cls="button";text="循环播放声音";left=213;top=168;right=514;bottom=304;z=1}
)
/*}}*/

winform.button.oncommand = function(id,event){
   
    thread.invoke(
        function(){
            
            import fsys.media;
            var media = fsys.media("\test.wav");
            for(i=1;3;1){
                media.play("wait")  
                media.seek(1);
            }
            media.close()   
        }
    )
}

winform.show();
win.loopMessage();

aaruser

Jacen.He 发表于 2018-9-7 12:39
你不是循环播放多次声音，而是同时播放多个声音，一张嘴不能同时说3句话，playSound也一样。你也没有到线程 ...

谢谢Jacen回复。

吃饭的比喻非常形象，受教了。

其实fsys.media的确是看了，不过看了playsound那里就没看下面的了，非常惭愧。