listview移除多条索引问题

x876526966

listview 通过 delItem() 移除多条索引问题


问题简述.通过 listview 的 delItem() 方法移除列表当中所选中的2条以上的索引只能清除其中一半  例：选中2条 移除掉1条，选中4条，只移除2条。【选中单条无问题】
         
        <1>选中这几行点击按钮移除所选行 如下图
           

        <2>点击按钮移除刚才选中的5,6,7,8,9行，会有几条没有移除成功，感觉是跳着移除的，跳过了第 6 和  8 条，不清楚是否我哪里写的不妥 如下图
           
           
可运行代码

1. import win.ui;
   
2. import console;
   
3. /*DSG{{*/
   
4. var winform = win.form(text="aardio form";right=759;bottom=469)
   
5. winform.add(
   
6. button={cls="button";text="删除选中的索引项";left=548;top=399;right=693;bottom=440;z=2};
   
7. listview={cls="listview";left=49;top=43;right=710;bottom=353;edge=1;fullRow=1;items={};z=1}
   
8. )
   
9. /*}}*/
   
10. 
    
11. winform.listview.setExtended(0x4/*_LVS_EX_CHECKBOXES*/)
    
12. winform.listview.insertColumn("id",100);
    
13. winform.listview.insertColumn("name",100);
    
14. winform.listview.insertColumn("age",150);
    
15. winform.listview.onnotify = function(id,code,ptr){
    
16. 
    
17.     if( code == 0xFFFFFF9B/*_LVN_ITEMCHANGED*/ ){
    
18.         
    
19.                  var nmListView = winform.listview.getNotifyMessage(code,ptr);
    
20.                 
    
21.                  if( !nmListView )
    
22.                          return;
    
23.                         
    
24.                          if( nmListView.uNewState & 0xF000/*_LVIS_STATEIMAGEMASK*/){
    
25.                                  var selIndex = nmListView.iItem;
    
26.                                 
    
27.                                  if( winform.listview.getChecked( selIndex ) ){
    
28.                                         
    
29.                                          winform.listview.setSelected(selIndex);
    
30.                                         
    
31.                                  }else {
    
32.                                         
    
33.                                          winform.listview.setSelected(selIndex,false);
    
34.                                         
    
35.                                  }
    
36.                          }  
    
37.          }
    
38. 
    
39. }
    
40. for(i=1;50;1){
    
41.        
    
42.         ind = winform.listview.addItem();       
    
43.         winform.listview.setItemText(ind,ind,1)
    
44.         winform.listview.setItemText("张三"+i,ind,2)
    
45.         winform.listview.setItemText("1"+i,ind,3)
    
46.        
    
47. }
    
48. 
    
49. winform.button.oncommand = function(id,event){
    
50.    
    
51.     var sel = winform.listview.selected;
    
52.    
    
53.        
    
54.         for(i=1;#sel;1){
    
55.                        
    
56.                 //winform.listview.selIndex = sel[ i ];
    
57.                 winform.listview.delItem(sel[ i ]);
    
58.                 console.log(sel[ i ])
    
59.         }
    
60.        
    
61. }
    
62. 
    
63. winform.show();
    
64. win.loopMessage();

复制代码

请教遇到过这个问题的朋友指点。感谢！

JacenHe

提问有那么多时间截图，
把跟你问题无关的代码删一下不会吗？！大家都很忙。

import win.ui;
/*DSG{{*/
var winform = win.form(text="aardio form";right=759;bottom=469)
winform.add(
button={cls="button";text="删除选中的索引项";left=548;top=399;right=693;bottom=440;z=2};
listview={cls="listview";left=49;top=43;right=710;bottom=353;edge=1;fullRow=1;items={};z=1}
)
/*}}*/

winform.listview.setExtended(0x4/*_LVS_EX_CHECKBOXES*/)
winform.listview.insertColumn("测试",100);
for(i=1;50)winform.listview.addItem("测试"+i);

winform.button.oncommand = function(id,event){
   
    var sel = winform.listview.selected;
    for(i=1;#sel;1){
        winform.listview.delItem(sel[ i ]);
    }  
}

winform.show();
win.loopMessage();

JacenHe

遇到问题以前先低头看一下函数说明不行？！答案都是准备好了的。
写的很清楚：selected指的是选中而不是勾选复选框。

而且你删节点，例如从2删到3，2删完了3就变成2了，
这种基础的逻辑错误可以自己先思考一下。

JacenHe

1、分清楚checked指的是勾选，selected指的是选中（不一定被勾选）
2、在数组中删成员，要从后面向前删。

正确写法：

import win.ui;
/*DSG{{*/
var winform = win.form(text="aardio form";right=759;bottom=469)
winform.add(
button={cls="button";text="删除选中的索引项";left=548;top=399;right=693;bottom=440;z=2};
listview={cls="listview";left=49;top=43;right=710;bottom=353;edge=1;fullRow=1;items={};z=1}
)
/*}}*/

winform.listview.setExtended(0x4/*_LVS_EX_CHECKBOXES*/)
winform.listview.insertColumn("测试",100);
for(i=1;50)winform.listview.addItem("测试"+i);

winform.button.oncommand = function(id,event){
   
    var sel = winform.listview.checked;
    for(i=#sel;1;-1){
        winform.listview.delItem(sel[ i ]);
    }
}

winform.show();
win.loopMessage();

x876526966

Jacen.He 发表于 2018-8-3 15:01
1、分清楚checked指的是勾选，selected指的是选中（不一定被勾选）
2、在数组中删成员，要从后面向前删。
...

感谢  

在上面的代码里我写了     勾选checked的同时做了选中索引的操作

1. winform.listview.onnotify = function(id,code,ptr){
   
2. 
   
3.     if( code == 0xFFFFFF9B/*_LVN_ITEMCHANGED*/ ){
   
4.         
   
5.                  var nmListView = winform.listview.getNotifyMessage(code,ptr);
   
6.                  
   
7.                  if( !nmListView )
   
8.                          return;
   
9.                         
   
10.                          if( nmListView.uNewState & 0xF000/*_LVIS_STATEIMAGEMASK*/){
    
11.                                  var selIndex = nmListView.iItem;
    
12.                                  
    
13.                                  if( winform.listview.getChecked( selIndex ) ){
    
14.                                          
    
15.                                          winform.listview.setSelected(selIndex);
    
16.                                          
    
17.                                  }else {
    
18.                                          
    
19.                                          winform.listview.setSelected(selIndex,false);
    
20.                                          
    
21.                                  }
    
22.                          }  
    
23.          }
    
24. 
    
25. }

复制代码

问题我知道了   删除顺序问题。无论用户怎么选哪怕跳着选  删除的时候也得从后向前删  

JacenHe

x876526966 发表于 2018-8-3 15:14
感谢  

在上面的代码里我写了     勾选checked的同时做了选中索引的操作

我没仔细看那段代码，我都是希望大家尽量简化代码，说明关键问题，这样方便我快刀斩乱麻

x876526966

Jacen.He 发表于 2018-8-3 15:01
1、分清楚checked指的是勾选，selected指的是选中（不一定被勾选）
2、在数组中删成员，要从后面向前删。
...

操作了一下，selected 用户操作如果不精准确实不容易选中。受教了！ 感谢