[请教] 计算空闲时间

快手风雨 · 发表于 2017-10-29 09:42:34

代码目的是在有鼠标或键盘输入事件时计算下上次离开到目前的空闲时间
在鼠标钩子中计算正常
在键盘钩子中空闲时间一直是0，不懂是什么原因，请大家指教!

import win.ui;
/*DSG{{*/
var winform = win.form(text="aardio form";right=759;bottom=469)
winform.add()
/*}}*/
import console
import mouse.hook;
import key.hook;
hkmouse = mouse.hook()
hkmouse.proc = function(msg,x,y,mouseData,injected,flags,timeStamp,extraInfo){
if( injected ) return;
var ret,info = ::User32.GetLastInputInfo( {INT size = 8;INT time} );
console.log("空闲时间："++win.getIdleTime() ,"本次触发时间："++timeStamp,"上次触发时间："++info.time)
}
hkkey = key.hook();
hkkey.proc = function(msg,vkcode,scancode,injected,flags,timeStamp,extraInfo){
if( injected ) return;
select(msg) {
case 0x100/*_WM_KEYDOWN*/ ,0x104/*_WM_SYSKEYDOWN*/{
var ret,info = ::User32.GetLastInputInfo( {INT size = 8;INT time} );
console.log("按下空闲时间："++win.getIdleTime() ,"本次触发时间："++timeStamp,"上次触发时间："++info.time)
}
case 0x101/*_WM_KEYUP*/,0x105/*_WM_SYSKEYUP*/{
var ret,info = ::User32.GetLastInputInfo( {INT size = 8;INT time} );
console.log("抬起空闲时间："++win.getIdleTime() ,"本次触发时间："++timeStamp,"上次触发时间："++info.time)
}
}
}
winform.onClose = function(hwnd,message,wParam,lParam){
hkmouse.close()
hkkey.close()
}
winform.show();
win.loopMessage();

复制代码

JacenHe · 发表于 2017-10-29 14:15:36

你已经按下键鼠鼠标了，就不叫空闲了，当然空闲时间是0.
键盘鼠标钩子会拖慢系统，尽量少用。

快手风雨 · 发表于 2017-10-29 14:36:15

实现本楼示例功能有什么效率高点的方法呢？

import win.ui;
/*DSG{{*/
var winform = win.form(text="aardio form";right=759;bottom=469)
winform.add()
/*}}*/
import console
import mouse.hook;
import key.hook;
import win;
var lasttime = 0
hkmouse = mouse.hook()
hkmouse.proc = function(msg,x,y,mouseData,injected,flags,timeStamp,extraInfo){
if( injected ) return;
var ret,info = ::User32.GetLastInputInfo( {INT size = 8;INT time} );
var idle = win.getIdleTime()
if(idle > 5000){
win.msgbox("空闲了"++ idle / 1000 ++ "秒")
}
}
winform.onClose = function(hwnd,message,wParam,lParam){
hkmouse.close()
}
winform.show();
win.loopMessage();

复制代码

JacenHe · 发表于 2017-10-29 15:05:21

win.getIdleTime() 就是得到系统空闲时间，
为什么你还要钩子去检测空闲时间。

快手风雨 · 发表于 2017-10-29 15:31:03

不用钩子想不到还可以用什么方法

要指定时间内连续没有任何操作，再次触碰来电脑时才弹出提示作息
比如：离开电脑连续超过10分钟没操作后，回到电脑时提醒
9：00时离开电脑
休息15分钟
再次打开电脑时间 9：15，这时碰下鼠标弹出提示离开了15分钟。

JacenHe · 发表于 2017-10-29 15:38:12

快手风雨发表于 2017-10-29 15:31
不用钩子想不到还可以用什么方法

要指定时间内连续没有任何操作，再次触碰来电脑时才弹出提示作息

你已经得到空闲时间了，还非要去下个钩子再去计算一遍空闲时间?!

最简单的你可以用个定时器，系统已经把空闲时间，以及空闲时间的变化都告诉你了

import win.ui;
/*DSG{{*/
var winform = win.form(text="aardio form";right=759;bottom=469)
winform.add(
edit={cls="edit";left=56;top=48;right=664;bottom=416;edge=1;multiline=1;z=1}
)
/*}}*/

winform.lastInputTick = win.getIdleTime()
var tmId = winform.setInterval(
10,function(){
      if( win.getIdleTime() < 100 ){
         var idle = winform.lastInputTick / 1000
         if( idle > 1 )
            winform.edit.printf("电脑上次闲置了：%.2d秒",idle);
      }
      winform.lastInputTick = win.getIdleTime();
}
)

winform.show();
win.loopMessage();

快手风雨 · 发表于 2017-10-29 15:57:03

多谢提示，用时钟方式解决问题。代码如下：

import win.ui;
/*DSG{{*/
var winform = win.form(text="aardio form";right=759;bottom=469)
winform.add()
/*}}*/
import console
var leave = false
tmid = winform.setInterval(
1000/*毫秒*/,
function(hwnd,msg,id,tick){
var idle = win.getIdleTime()
if(leave and idle < 5000){
leave = false
console.log("离开了"++ leaveIdle)
leaveIdle = 0
}
if(idle>5000){
leave = true
console.log(idle)
leaveIdle = idle
}
}
);
winform.show();
win.loopMessage();

复制代码

用户名		自动登录	找回密码
密码			注册会员