如何调用按钮的点击事件？

lightsword

比如当按钮取得焦点时，用ENTER键来调用此按钮的点击事件

1. 
   
2. import win.ui;
   
3. import winex
   
4. /*DSG{{*/
   
5. var winform = ..win.form(text="aardio Form";right=599;bottom=399)
   
6. winform.add(
   
7. button={cls="button";text="button";left=169;top=141;right=232;bottom=170;z=1}
   
8. )
   
9. /*}}*/
   
10. winform.button.setFocus()
    
11. winform.button.wndproc = function(hwnd,message,wparam,lparam){
    
12.         if(message = 0x101/*_WM_KEYUP*/ && wparam = 0xD/*_VK_RETURN*/){
    
13.                 winex.click(owner.hwnd)
    
14.     }
    
15. }
    
16. winform.button.oncommand = function(id,event){
    
17.                 winform.msgbox("clicked")
    
18. }
    
19. winform.show();
    
20. win.loopMessage();
    
21. 
    

复制代码

这是用模拟的方法，请问下，有没有其他直接的调用呢？

编程

winform.button.oncommand() 直接调用按钮事件就可以了，他不就是一个函数么？！
没有任何必要绕那么大一个弯子.

lightsword

谢谢版主的答复，
可如何在按钮上用按键来达到鼠标点击的效果？
既是当按键取得焦点后，通过键盘上的ENTER键（或其他按键），取得和用鼠标点击此按钮的效果？
用winform.button.oncommand() 好像不能捕获按键的消息吧，

编程

lightsword 发表于 2014-2-9 12:11
谢谢版主的答复，
可如何在按钮上用按键来达到鼠标点击的效果？
既是当按键取得焦点后，通过键盘上的ENTE ...

winform.button.oncommand() 就是鼠标点击此按钮的效果。
至于按钮默认设置你能按空格键代替鼠标点击，而回车键通常是用来作对话框快揵键，
例如一个登录对话框，你输好用户名、密码，不会把焦点移到登录按钮上才按回车键，而是直接按回车键触发默认按钮。

回车键总是触发第一个按钮，
所以你可以在对话框设计器中右键点击默认按钮，在弹出菜单中点击排序到【最后面】他就可以响应回车键了。


如果你希望取而代之的是用户必须将焦点移动到按钮、然后才能响应回车键，你需要添加下面的代码修改按钮样式：

//通知按钮响应回车按键
winform.button2.modifyStyle(,0x1/*_BS_DEFPUSHBUTTON*/)

但不建议你这样做，因为按钮需要得到焦点才响应回车、或者对话框上出现多个默认按钮、这都会不必要的制造混乱。

大将军

下方这个是从自己写的小程序中截出来的：

1. 
   
2. //调用『回复』按钮
   
3. mainForm.edit.wndproc = function(hwnd,message,wParam,lParam){
   
4.         select(message) {
   
5.                 case 0x100/*_WM_KEYDOWN*/{
   
6.                         if( key.getState("CTRL") and key.getState("ENTER") ){
   
7.                                 mainForm.btn_reply.oncommand()
   
8.                                 win.delay(1); mainForm.edit.text = "" //加DELAY是为了能删除"ENTER"字符
   
9.                         }
   
10.                         if( key.getState("CTRL") and key.getState("A") ){
    
11.                                 mainForm.edit.selectAll() //全选回复区的内容
    
12.                         }
    
13.                 }
    
14.         }
    
15. }
    

复制代码

编程

大将军 发表于 2014-2-9 17:20
下方这个是从自己写的小程序中截出来的：

感谢分享代码，不过代码中存在一些小问题。

1、取CTRL键状态不必要的重复调用 key.getState("CTRL") ，应当在前面加个局部变量，例如：
var ctrl = key.getState("CTRL") 以避免重复调用，程序的性能是点滴挤出来的，所以应注意这些细节。

2、可以使用 wParam 直接取到当前按键虚拟码，不需要使用 key.getState("ENTER") 这种方式。

3、快捷键实际上可以在 mainForm.edit.translateAccelerator  事件中处理，因为这个是专门处理键盘消息的，
这样不必增加一个回调函数减少了一次消息调用过程，并且他过滤了其他的消息只会处理键盘消息，在消息处理中简单的返回true就可以阻止默认的消息处理（文本框里不会输入回车）、不必再去清空文本框。

下面是一个完整的示例：

1. 
   
2. import win.ui;
   
3. /*DSG{{*/
   
4. var mainForm = ..win.form(text="aardio Form";right=599;bottom=399)
   
5. mainForm.add(
   
6. button={cls="button";text="button";left=262;top=339;right=518;bottom=379;z=2};
   
7. edit={cls="edit";text="edit";left=64;top=51;right=550;bottom=313;edge=1;multiline=1;z=1}
   
8. )
   
9. /*}}*/
   
10. 
    
11. mainForm.button.oncommand = function(id,event){
    
12.         mainForm.msgbox( mainForm.button.text );
    
13. }
    
14. 
    
15. import key;
    
16. mainForm.edit.translateAccelerator = function( msg ){
    
17.     var ctrl = key.getState("CTRL");
    
18.     var shift =  key.getState("SHIFT");
    
19.     var alt = key.getState("ALT");
    
20.     if( msg.wParam == 'A'#  && ctrl && !alt && !shift){
    
21.         mainForm.edit.selectAll();
    
22.         return true;
    
23.     }
    
24.     elseif( ctrl &&  msg.wParam == 0xD/*_VK_RETURN*/ ){
    
25.             if( msg.message == 0x100/*_WM_KEYDOWN*/ )
    
26.                     mainForm.button.oncommand()
    
27.                 return true;
    
28.     }
    
29. }
    
30. 
    
31. mainForm.show()
    
32. win.loopMessage();
    
33. 
    

复制代码

或者用下面的方法，
在处理对话框快捷键的isDialogMessage事件中也可以自定义快捷键，关键代码如下：

1. 
   
2. import key;
   
3. mainForm.isDialogMessage = function(hwnd,msg){
   
4. 
   
5.     if(  msg.wParam == 0xD/*_VK_RETURN*/ && msg.hwnd == mainForm.edit.hwnd && key.getState("CTRL") ){
   
6.         msg.hwnd = mainForm.button.hwnd;
   
7.     }
   
8.     return win.isDialogMessage(hwnd,msg);
   
9. }
   

复制代码

lightsword

多谢编程老师，受教了！