HTMLayout中SELECT 选中项的数值获取方

wznjsy · 发表于 2013-7-16 19:34:19

本帖最后由 wznjsy 于 2013-7-16 22:43 编辑

HTMLayout 获取SELECT 选中项的时候，如果VALUE是数字，按照常规的获取方式有可能得不到想要的结果。昨天有幸得到 lujjjh 提供代码，不敢独享。放在这里，以便大家查阅。谢谢 lujjjh

原因在4楼。

import win.ui;
/*DSG{{*/
winform = ..win.form( bottom=399;parent=...;text="aardio Form";right=599 )
winform.add(
layoutWindow={ dr=1;dl=1;bottom=382;right=580;left=10;multiline=1;top=12;notify=1;z=1;db=1;dt=1;cls="edit" }
)
/*}}*/
import web.layout;
io.open();
wbLayout = web.layout(winform.layoutWindow);
wbLayout.html =/***
<html>
<body>
<div id="my-button" >查看北京或者上海的值</div>
<select id="province" style="margin-top: 10">
<option value="0.800">北京</option>
<option value="0100">上海</option>
<option value="0111">广州</option>
</select>
</body>
</html>
***/
io.open()
var layoutEle = wbLayout.getEle("my-button")
layoutEle.onMouseClick = function( ltTarget,ltEle,x,y,mouseParams ) {
io.print("错误的", wbLayout.getEle("province").value);
io.print("正确的",wbLayout.$1("#province option:checked").getAttribute("value"));
}
//调用此函数节点可响应HTML事件
layoutEle.attachEventHandler();
winform.show()
win.loopMessage();

复制代码

落伍者 · 发表于 2013-7-16 19:55:55

import win.ui;
/*DSG{{*/
winform = ..win.form( bottom=399;parent=...;text="aardio Form";right=599 )
winform.add(
layoutWindow={ dr=1;dl=1;bottom=382;right=580;left=10;multiline=1;top=12;notify=1;z=1;db=1;dt=1;cls="edit" }
)
/*}}*/
import web.layout;
wbLayout = web.layout(winform.layoutWindow);
wbLayout.html =/***
<html>
<body>
<div id="my-button" >查看北京或者上海的值</div>
<select id="province" style="margin-top: 10">
<option value="0.800">北京</option>
<option value="0100">上海</option>
<option value="0111">广州</option>
</select>
</body>
</html>
***/
var ele=wbLayout.queryEle("#province")
ele.onSelectSelectionChanged = function (ltTarget,ltEle,reason,behaviorParams){
io.print(ele.value);
}
ele.attachEventHandler()
io.open();
winform.show()
win.loopMessage();

复制代码

wznjsy · 发表于 2013-7-16 20:30:01

落伍者发表于 2013-7-16 19:55

这个获取到的值还是错误的哦

lujjjh · 发表于 2013-7-16 22:25:33

不是说会错误，而是 HTML 中无论属性值是字符串还是数值，都必须加上引号，HTMLayout 又会猜测你的 value 的类型，自动转换成数字了。

wznjsy · 发表于 2013-7-16 22:42:00

嗯嗯已经修正。

roger · 发表于 2013-7-17 14:59:42

value里可以写数值的，你写 0100 就是8进制的64了。
只有value属性才能支持8进制的数值。如果不需要这个功能可以用其他的名字就行了，例如

wbLayout.queryEle("#province option:checked").value2

roger · 发表于 2013-7-17 15:05:19

或者你强制他是一个字符串也可以，HTML里写:

<option value="$0.800">北京</option>

aardio里这样写:

string.right( wbLayout.getEle("province").value,-2 )

wznjsy · 发表于 2013-7-19 10:05:03

办法始终比问题多。谢谢 Roger

满月星光 · 发表于 2013-7-25 07:13:26

强。学习了一个小窍门

a38809972 · 发表于 2015-7-17 11:10:56

怎么添加一个option啊?

[HTML] HTMLayout中SELECT 选中项的数值获取方